上一节:
下一节:

  汇编语言 系统调用

  • 系统调用

    系统调用是用户空间和内核空间之间接口的API。我们已经使用了系统调用。sys_write和sys_exit分别用于写入屏幕和退出程序。

  • Linux系统调用

    您可以在汇编程序中使用Linux系统调用。您需要执行以下步骤才能在程序中使用Linux系统调用-
    • 将系统呼叫号放入EAX寄存器中。
    • 将参数保存到系统调用中的寄存器EBX，ECX等中。
    • 调用相关的中断（80h）。
    • 结果通常在EAX寄存器中返回。
    有六个寄存器，用于存储所用系统调用的参数。这些是EBX，ECX，EDX，ESI，EDI和EBP。这些寄存器采用从EBX寄存器开始的连续参数。如果有六个以上的自变量，则第一个自变量的存储位置将存储在EBX寄存器中。
    以下代码片段显示了系统调用sys_exit的使用- 
    
mov     eax,1           ; system call number (sys_exit)
int     0x80            ; call kernel
    以下代码片段显示了系统调用sys_write的使用- 
    
mov     edx,4           ; message length
mov     ecx,msg         ; message to write
mov     ebx,1           ; file descriptor (stdout)
mov     eax,4           ; system call number (sys_write)
int     0x80            ; call kernel
    所有系统调用及其编号（在调用int 80h之前放入EAX的值）都列在/usr/include/asm/unistd.h中
    下表显示了本教程中使用的一些系统调用-
    ％eax 名称 ％ebx ％ecx ％edx ％esx ％edi
    1 sys_exit int - - - -
    2 sys_fork struct pt_regs - - - -
    3 sys_read unsigned int char * size_t - -
    4 sys_write unsigned int const char * size_t - -
    5 sys_open const char * int int - -
    6 sys_close unsigned int - - - -

  • 示例

    以下示例从键盘读取一个数字并将其显示在屏幕上- 
    
section .data                           ;数据段
   userMsg db 'Please enter a number: ' ;询问用户键盘输入一个数字
   lenUserMsg equ $-userMsg             ;消息的长度
   dispMsg db 'You have entered: '
   lenDispMsg equ $-dispMsg                 

section .bss           ;未初始化的数据
   num resb 5
        
section .text          ;代码段
   global _start
        
_start:                ;用户提示
   mov eax, 4
   mov ebx, 1
   mov ecx, userMsg
   mov edx, lenUserMsg
   int 80h

   ;读取并存储用户输入
   mov eax, 3
   mov ebx, 0
   mov ecx, num  
   mov edx, 5          ;该信息的5个字节(数字，1表示符号)
   int 80h
        
   ;输出消息'You have entered:'
   mov eax, 4
   mov ebx, 1
   mov ecx, dispMsg
   mov edx, lenDispMsg
   int 80h  

   ;输出输入的数字
   mov eax, 4
   mov ebx, 1
   mov ecx, num
   mov edx, 5
   int 80h  
    
   ; Exit code
   mov eax, 1
   mov ebx, 0
   int 80h
    编译并执行上述代码后，键盘输入交互，将产生以下结果 - 
    
Please enter a number:
66666
You have entered:66666
上一节:
下一节: